remacs的世界

大模型时代我们怎么玩Emacs：5. Org 文件导出为 Markdown 文件时的链接改造

Thu, 11 Jul 2024 06:37:32 +0800

1 前言
2 Org 文件导出为 Markdown 文件时的链接改造
- 2.1 背景
- 2.2 向大模型描述问题
- 2.3 调试和反馈
- 2.4 可能是 Org-mode 的一个 bug
- 2.5 增加后处理解决这个 bug
- 2.6 最终生成的代码
- 2.7 最终的效果
3 结语

1 前言 🔗

在大模型时代，一切皆有可能。对于 Emacs 同样如此，大模型拉低学习了 Emacs 的门槛，我们通过大模型可以做到以前我们敢想不敢做，或敢做没时间做，或有时间不会做的事。

今天继续这个新的系列，跟大家分享在大模型时代，我们可以如何“玩” Emacs，我们应该怎么用大模型来满足自己对 Emacs 使用的需求。

2 Org 文件导出为 Markdown 文件时的链接改造 🔗

2.1 背景 🔗

我经常使用 Emacs 的 Org-mode 和 honkit 软件来写产品手册或技术文档。我会先用 Org-mode 来写原始的文档，然后导出为 Markdown 文件，然后在命令行通过 npx honkit serve 命令生成静态站点，打个包把所有的 HTML 发给前端部署一下，整个产品手册就写完了。成品大概长下面这样：

整个工作流非常顺畅，就是有一点很烦人，我在 Org 文档里会有很多截图，我的截图会带一些属性，例如 width, class 等，在导出为 Markdown 时，这些属性会丢失。

下面是我在 Org 文件里的截图的文本的一个示例，通过 #+ATTR_HTML: 会添加一些额外的属性：

#+DOWNLOADED: screenshot @ 2024-07-11 四 06:41:14
#+CAPTION:
#+ATTR_ORG: :width 400
#+ATTR_LATEX: :width 0.5\linewidth :float nil
#+ATTR_HTML: :width 400 :class zoomImage
[[file:org文件导出为Markdown文件时的链接改造.assets/demo.png]]

在实际导出为 Markdown 文件后，链接如下：

![img](org文件导出为Markdown文件时的链接改造.assets/demo.png)

可以看到丢失了 width, class 等属性，这样会导致最终生成网页里的图片的大小会失控，有的时候我明明希望它以 400px 显示，却以 800px 来显示，看上去很不协调，我更希望的是下面这张图：

Markdown 天然支持 <img src="" width="" alt="" class=""> 这样的标签，因此自然而然的就想，是不是可以让 Org-mode 在导出为 Markdown 格式时，将 Markdown 格式的链接做一个转换，同时带上 width 这些属性。

2.2 向大模型描述问题 🔗

在向大模型描述问题的时候，请注意，最好使用实际的例子，比如实际的 Org 文档里的图片链接，导出为 Markdown 文档之后的链接，并写明期望的结果：

2.3 调试和反馈 🔗

在拿到大模型给的初版代码时，我们需要进行试运行，并将相应的报错（如有）的信息给到大模型，让大模型调整代码。

2.4 可能是 Org-mode 的一个 bug 🔗

在调试许久之后，最终得到了如下的代码：

(defun my-org-md-export-image-links (text backend info)
  "Convert image file links to HTML img tags with attributes on Markdown export."
  (when (org-export-derived-backend-p backend 'md)
    (replace-regexp-in-string
     "\\!\\[.*\\](\\(.*\\))"  ;; 更加严格匹配整个 Markdown 图片链接
     (lambda (m)
       (let* ((path (match-string 1 m))
              ;; 从 Org 文件解析中寻找对应的链接元素
              (link (org-element-map (org-element-parse-buffer) 'link
                      (lambda (el)
                        (when (string= (org-element-property :path el) path)
                          el))
                      nil t 'link))
              ;; 提取链接的父元素中的 HTML 属性
              (attributes (and link (org-export-read-attribute :attr_html (org-element-property :parent link))))
              (width (plist-get attributes :width))
              (class (plist-get attributes :class)))
         ;; 生成带属性的 HTML <img> 标签
         (if attributes  ; 只有当找到属性时才替换
             (format "<img src=\"%s\" alt=\"%s\" %s %s>"
                     path
                     (file-name-nondirectory path)
                     (if width (format "width=\"%s\"" width) "")
                     (if class (format "class=\"%s\"" class) ""))
           m)))  ; 如果没有属性或未找到匹配的元素，则不修改
     text)
    ))

(add-to-list 'org-export-filter-link-functions
             'my-org-md-export-image-links)

执行了这段代码，我们发现，生成的新的链接，是带上原有图片的 width 等属性了，但是生成的链接总是多了一些额外的字符串，我自己判断是在链接做正则替换的时候出了问题。

![i<img src="appComponents.assets/img_20231008_094849.png" alt="img" width="300" class="zoomImage">omponents.assets/img_20231008_094849.png)

然而，更有趣的是，即使我使用 emacs -Q 来启动 Emacs，执行上面的代码，依然存在这样的问题。

为了检验正则表达式有无问题，我写了下面的一个小函数来做测试，发现测试结果是符合预期的 <img src=\"appTest.assets/img_20231007_181409.png\" alt=\"img_20231007_181409.png\" 400 zoomImage>, 并没有出现上面的情况:

(replace-regexp-in-string
 "\\!\\[.*?\\](\\([^)]+\\))"
 (lambda (m)
   (let* ((path (match-string 1 m)))
     (if t
         (format "<img src=\"%s\" alt=\"%s\" width=\"%s\" class=\"%s\">"
                 path
                 (file-name-nondirectory path)
                 "400"
                 "zoomImage")
       m)))
 "BalaBala...：

![img](appTest.assets/img_20231007_181311.png)

Balabala：

![img](appTest.assets/img_20231007_181409.png)")

“BalaBala…：\n\n<img src=\“appTest.assets/img_20231007_181311.png\” alt=\“img_20231007_181311.png\” width=\“400\” class=\“zoomImage\">\n\nBalabala：\n\n<img src=\“appTest.assets/img_20231007_181409.png\” alt=\“img_20231007_181409.png\” width=\“400\” class=\“zoomImage\">”

那么，此时此刻，凭我的知识和代码能力，是无能为力了，只能姑且认为这是 Org-mode 的一个隐藏 bug 吧。

2.5 增加后处理解决这个 bug 🔗

为了解决这个问题，我想到我们能不能在最终生成完的 Markdown 文件里找到所有 ![i<img src="xxx" ...>components.assets/...png) 这样的字符串，将尖括号两边的多余字符串给删掉来解决呢？

于是就有了下面这一次与大模型的对话和尝试：

最终经过尝试，通过下面这一段代码，在导出为 Markdown 后，在生成的 markdown 文件里处理这些有问题的链接：

(defun fix-markdown-image-links ()
  "Fix image links in the exported Markdown file."
  (goto-char (point-min))
  (while (re-search-forward "!\\[i\\(<img.*?\">\\).*" nil t)
    (replace-match "\\1")))

(defun my/org-export-to-markdown (org &rest args)
  "Post-process the generated Markdown file."
  (let ((output-file (concat (file-name-sans-extension (buffer-file-name)) ".md")))
    (when (file-exists-p output-file)
      (find-file output-file)
      ;; 在这里进行你需要的文本处理操作，例如添加特定文本
      (fix-markdown-image-links)
      ;; 保存并关闭文件
      (save-buffer)
      (kill-buffer))))

(advice-add 'org-md-export-to-markdown :after 'my/org-export-to-markdown)
(advice-add 'org-gfm-export-to-markdown :after 'my/org-export-to-markdown)

完美！

2.6 最终生成的代码 🔗

(defun my-org-md-export-image-links (text backend info)
  "Convert image file links to HTML img tags with attributes on Markdown export."
  (when (org-export-derived-backend-p backend 'md)
    (replace-regexp-in-string
     "\\!\\[.*\\](\\(.*\\))"  ;; 更加严格匹配整个 Markdown 图片链接
     (lambda (m)
       (let* ((path (match-string 1 m))
              ;; 从 Org 文件解析中寻找对应的链接元素
              (link (org-element-map (org-element-parse-buffer) 'link
                      (lambda (el)
                        (when (string= (org-element-property :path el) path)
                          el))
                      nil t 'link))
              ;; 提取链接的父元素中的 HTML 属性
              (attributes (and link (org-export-read-attribute :attr_html (org-element-property :parent link))))
              (width (plist-get attributes :width))
              (class (plist-get attributes :class)))
         ;; 生成带属性的 HTML <img> 标签
         (if attributes  ; 只有当找到属性时才替换
             (format "<img src=\"%s\" alt=\"%s\" %s %s>"
                     path
                     (file-name-nondirectory path)
                     (if width (format "width=\"%s\"" width) "")
                     (if class (format "class=\"%s\"" class) ""))
           m)))  ; 如果没有属性或未找到匹配的元素，则不修改
     text)
    ))

(add-to-list 'org-export-filter-link-functions
             'my-org-md-export-image-links)

(defun fix-markdown-image-links ()
  "Fix image links in the exported Markdown file."
  (goto-char (point-min))
  (while (re-search-forward "!\\[i\\(<img.*?\">\\).*" nil t)
    (replace-match "\\1")))

(defun my/org-export-to-markdown (org &rest args)
  "Post-process the generated Markdown file."
  (let ((output-file (concat (file-name-sans-extension (buffer-file-name)) ".md")))
    (when (file-exists-p output-file)
      (find-file output-file)
      ;; 在这里进行你需要的文本处理操作，例如添加特定文本
      (fix-markdown-image-links)
      ;; 保存并关闭文件
      (save-buffer)
      (kill-buffer))))

(advice-add 'org-md-export-to-markdown :after 'my/org-export-to-markdown)
(advice-add 'org-gfm-export-to-markdown :after 'my/org-export-to-markdown)

2.7 最终的效果 🔗

原始 org 文档：

* title

hello, world!

#+DOWNLOADED: screenshot @ 2024-06-27 四 15:41:48
#+CAPTION:
#+ATTR_ORG: :width 800
#+ATTR_LATEX: :width 1.0\linewidth :float nil
#+ATTR_HTML: :width 800 :class zoomImage
[[file:temp.assets/img_20240627_154148.png]]

Good!

最终生成的 markdown 文档：

- [title](#org79702d9)


<a id="org79702d9"></a>

# title

hello, world!

<img src="temp.assets/img_20240627_154148.png" alt="img_20240627_154148.png" width="800" class="zoomImage">

Good!

3 结语 🔗

今天这个案例，我们无法通过大模型一次性地解决问题，我们可以根据需要，让大模型辅助人，人需要思考，很多时候，人的思路比大模型更重要，人能更好地指导大模型如何服务于人。

后续，将会继续分享几个案例。

org 文件导出为 HTML 的 css 改造
…

我也会持续的使用 ChatGPT 和 Emacs，持续分享我的心得，感谢您的阅读。

大模型时代我们怎么玩Emacs：4. Org 文件里的链接和反链改造

Mon, 10 Jun 2024 21:00:39 +0800

1 前言
2 Org 文件里的链接和反链改造
- 2.1 背景
- 2.2 org-super-links
- 2.3 org-super-links 的不足
- 2.4 改造 org-super-links 插件
- 2.5 最终效果
- 2.6 最终生成的代码
3 结语

1 前言 🔗

今天继续这个新的系列，跟大家分享在大模型时代，我们可以如何“玩” Emacs，我们应该怎么用大模型来满足自己对 Emacs 使用的需求。

2 Org 文件里的链接和反链改造 🔗

2.1 背景 🔗

我通过 Org mode 和 Denote 包来构筑我的知识体系。Org mode 有一个很好的功能就是链接，他可以让你在某一个 Org 文件内，增加链接到另外一个文件的某个标题行，这样能让知识链接成网，长期坚持，好处多多。

Org mode 自带一个 org-store-link 命令，可以将当前位置记录下来，然后通过 org-insert-link 命令插入到其他的 Org 文件：

但这个功能有一个不够完善的地方，就是它的链接是单向的，我们从上面那个例子可以看到在文档的最末，链接到了 第二级 这个标题行，但是在 第二级 标题行，我们并不知道这个标题行被链接到哪些地方。

2.2 org-super-links 🔗

org-super-links 就是用来完善这个需求的。有了这个插件，我们可以通过 org-super-links-store-link 来存储某个位置，然后通过 org-super-links-insert-link 来插入链接：

2.3 org-super-links 的不足 🔗

通过 org-super-links 插件确实能够在我们插入某个链接时，在源文件的标题行以 drawer 来显示反链信息。

对我来说，如果能在插入的地方所在的标题行也以 drawer 的方式显示插入链接信息，那就更加完美了，相当于在插入和被插入的标题行，都在标题行下以 drawer 的方式来记录链接信息，我们无论在哪，都能很方便的看到彼此的双向信息。这就是本次实验的初衷。

2.4 改造 org-super-links 插件 🔗

这一次的改造，跟之前几次不同，我们换了一种方式，我们将 org-super-links 插件的主体源代码全部 copy 复制到 ChatGPT 中，得益于 GPT-4o 强大的窗口 token 数，整个插件的源代码都可以被 ChatGPT 阅读，并基于它的理解，我们进行相关的改造。

接着，就要逐步地清晰地描述自己的需求：

接着是不断的测试，并将错误情况告诉 ChatGPT，让它不断的调整代码，以及加入这段最重要的需求描述：

2.5 最终效果 🔗

通过 org-super-links-store-link 来存储源文件的标题行位置
在目标位置，通过 org-super-links-insert-link 来插入
1. 当目标位置在一个标题行上，以 drawer 的方式来记录链接信息，同时在源文件标题行以 drawer 方式记录反链信息
2. 当目标位置不在标题行上，即在正文中，那不仅仅以 drawer 的方式来记录链接信息，同时在光标处插入该链接信息，并且在源文件标题行以 drawer 方式记录反链信息
这样，所有的链接和反链信息都可以在源文件标题行和目的文件标题行的 drawer 清晰的看到，并且不妨碍在正文中的链接

2.6 最终生成的代码 🔗

  ;; 为了实现在存储位置时带上文件和标题行的信息，进行了如下的魔改
  (defun org-super-links-store-link (&optional GOTO KEYS)
    "Store a point to the register for use in function `org-super-links-insert-link'.
This is primarily intended to be called before `org-capture', but
could possibly even be used to replace `org-store-link' IF
function `org-super-links-insert-link' is used to replace `org-insert-link'.  This
has not been thoroughly tested outside of links to/form org files.
GOTO and KEYS are unused."
    (interactive "P")
    (ignore GOTO)
    (ignore KEYS)
    (save-excursion
      (let ((c1 (make-marker))
            (headline (org-get-heading t t t t)))  ;; 获取标题行
        (set-marker c1 (point) (current-buffer))
        (set-register ?^ (cons c1 headline))  ;; 存储标记和标题行
        (message "Link copied with headline: %s" headline))))

  (defun org-super-links-insert-link ()
    "Insert a super link from the register."
    (interactive)
    (let* ((target (get-register ?^)))
      (if target
          (let ((marker (car target))
                (headline (cdr target)))
            (org-super-links--insert-link marker headline)
            (set-register ?^ nil))
        (message "No link to insert!"))))

  (defun org-super-links--insert-link (target headline &optional no-forward)
    "Insert link to marker TARGET at current `point`, and create backlink to here.
Include HEADLINE in the link.
If NO-FORWARD is non-nil skip creating the forward link.  Currently only used when converting a link."
    (let* ((source (point-marker))
           (source-headline (org-get-heading t t t t))
           (source-link (org-super-links-links-action source 'org-super-links-pre-link-hook))
           (target-link (org-super-links-links-action target 'org-super-links-pre-backlink-hook))
           (source-formatted-link (org-super-links-link-builder source-link))
           (target-formatted-link (org-super-links-link-builder target-link))
           (source-file (file-relative-name (buffer-file-name (marker-buffer source))
                                            (file-name-directory (buffer-file-name (marker-buffer target)))))
           (target-file (buffer-file-name (marker-buffer target)))
           (source-link (format "file:%s::%s" source-file source-headline))
           (target-link (format "file:%s::%s" target-file headline)))
      (with-current-buffer (marker-buffer target)
        (save-excursion
          (goto-char (marker-position target))
          (when (derived-mode-p 'org-mode)
            (org-super-links-insert-backlink source-link source-headline))))
      (unless no-forward
        (with-current-buffer (marker-buffer source)
          (save-excursion
            (goto-char (marker-position source))
            (if (org-at-heading-p)
                (org-super-links-insert-relatedlink target-link headline)
              (org-super-links-insert-inline-link target-link headline source-headline)))))))

  (defun org-super-links-insert-inline-link (target-link headline source-headline)
    "Insert TARGET-LINK with HEADLINE at point and add related drawer at current heading."
    ;; (insert (org-super-links-link-prefix))
    (org-insert-link nil target-link headline)
    (insert (org-super-links-link-postfix))
    (org-back-to-heading)
    (org-super-links-insert-relatedlink target-link headline))

  (defun org-super-links-insert-backlink (link desc)
    "Insert backlink to LINK with DESC.
Where the backlink is placed is determined by the variable `org-super-links-backlink-into-drawer`."
    (let* ((org-log-into-drawer (org-super-links-backlink-into-drawer))
           (description (org-super-links-default-description-formatter link desc))
           (beg (org-log-beginning t)))
      (goto-char beg)
      (insert (org-super-links-backlink-prefix))
      (insert (org-link-make-string link description))
      (insert (org-super-links-backlink-postfix))
      (org-indent-region beg (point))))

  (defun org-super-links-insert-relatedlink (link desc)
    "Insert LINK with DESC into related drawer."
    (let* ((org-log-into-drawer (org-super-links-related-into-drawer))
           (drawer-name (or org-log-into-drawer "RELATED"))
           (beg (org-log-beginning t)))
      (goto-char beg)
      (unless (org-at-heading-p)
        (org-back-to-heading t))
      (org-narrow-to-subtree)
      (let ((drawer-beg (re-search-forward (format ":%s:" drawer-name) nil t)))
        (if drawer-beg
            (progn
              (goto-char drawer-beg)
              (forward-line)
              (insert (org-super-links-link-prefix))
              (org-insert-link nil link desc)
              (insert (org-super-links-link-postfix) "\n")
              (org-indent-region drawer-beg (point)))
          (goto-char (point-max))
          (insert (format ":%s:\n" drawer-name))
          (insert (org-super-links-link-prefix))
          (org-insert-link nil link desc)
          (insert (org-super-links-link-postfix) "\n")
          (insert (format ":%s:\n" "END"))
          (org-indent-region beg (point))))
      (widen)))

  (defun org-super-links-related-into-drawer ()
    "Name of the related drawer, as a string, or nil.
This is the value of `org-super-links-related-into-drawer`.  However, if the
current entry has or inherits a RELATED_INTO_DRAWER property, it will
be used instead of the default value."
    (let ((p (org-entry-get nil "RELATED_INTO_DRAWER" 'inherit t)))
      (cond ((equal p "nil") nil)
            ((equal p "t") org-super-links-related-drawer-default-name)
            ((stringp p) p)
            (p org-super-links-related-drawer-default-name)
            ((stringp org-super-links-related-into-drawer) org-super-links-related-into-drawer)
            (org-super-links-related-into-drawer org-super-links-related-drawer-default-name))))

3 结语 🔗

今天这个案例，是另外一种思路，我们将整个插件的源代码通过提示词一起给到大模型，由大模型做整体的理解和记忆，然后基于整体源代码，提出我们的需求、进行调试，最终达到我们的目标。

后续，将会继续分享几个案例。

org 文件导出为 HTML 的 css 改造
…

我也会持续的使用 ChatGPT 和 Emacs，持续分享我的心得，感谢您的阅读。

大模型时代我们怎么玩Emacs：3. Org mode 代码块执行错误信息优化

Thu, 23 May 2024 21:13:54 +0800

1 前言
2 Org mode 代码块执行出错信息优化
- 2.1 背景
- 2.2 正确的描述我们的问题
- 2.3 测试以及需求累进的描述
- 2.4 最终的效果
- 2.5 最终的代码
3 结语

1 前言 🔗

今天继续这个新的系列，跟大家分享在大模型时代，我们可以如何“玩” Emacs，我们应该怎么用大模型来满足自己对 Emacs 使用的需求。

上一篇关于根据 jieba 分词移动和删除的文章，只是提供了一个思路，后来经 LuciusChen 道友推荐，我试用了 roife 大佬的 emt 包，利用 MacOS 自带的 Tokenizer 来分词，体验更加顺滑，强烈推荐！

2 Org mode 代码块执行出错信息优化 🔗

2.1 背景 🔗

我非常喜欢 Org mode，实际上我现在基本上不太使用 Office。Org mode 里有一个我非常喜欢的特性就是代码块。这使得我能在 Org 文件里通过代码块来编写一些小的程序，用一个专业术语叫「文学编程」。它能让在遇到某些任务时，一边记录你的思路，一边通过代码块以及 :noweb 或 :session 的特性，如流水般的往前行。

然而代码块有一个很让人难受的默认行为就是：当代码块里的代码出现错误时，它的报错不是在 Org 文件的 +RESULTS: 部分显示，而是新开了一个叫 *Org-Babel Error Output* 的 buffer 显示。

这在体验上不够连贯和统一，于是我开始了这次尝试。

2.2 正确的描述我们的问题 🔗

今天这个样例跟之前的不同，我们不是直接描述需求，而是先把相关函数的源代码给到 ChatGPT，让后直接让 ChatGPT 根据我们的描述来进行改造。

2.3 测试以及需求累进的描述 🔗

2.4 最终的效果 🔗

2.5 最终的代码 🔗

(defun my/org-babel-eval (command query)
  "Run COMMAND on QUERY.
Return standard output and error produced by COMMAND.

Writes QUERY into a temp-buffer that is processed with
`org-babel--shell-command-on-region'."
  (let ((error-buffer (get-buffer-create " *Org-Babel Error*")) exit-code)
    (with-current-buffer error-buffer (erase-buffer))
    (with-temp-buffer
      (insert query "\n")
      (setq exit-code
            (org-babel--shell-command-on-region
             command error-buffer))
      (let ((stderr (with-current-buffer error-buffer (buffer-string)))
            (stdout (buffer-string)))
        (concat stdout
                (if (not (string-empty-p stderr))
                    (concat "\n--- STDERR ---\n" stderr)
                  ""))))))

(advice-add #'org-babel-eval :override #'my/org-babel-eval)

3 结语 🔗

今天这个案例，是一个简单的案例，但是我们的处理思路有一些变化，不是直接描述需求，而是直接将需要改造的函数源代码给到 ChatGPT，让它按照我们的要求进行改造，最后调试，完成我们的目标。

后续，将会继续分享几个案例。

org-super-links 链接与反链改造
…

我也会持续的使用 ChatGPT 和 Emacs，持续分享我的心得，感谢您的阅读。

大模型时代我们怎么玩Emacs：2. 中文按词移动和删除

Tue, 21 May 2024 16:26:43 +0800

1 前言
2 大模型
3 中文按词移动和删除
- 3.1 背景
- 3.2 正确的描述我们的问题
- 3.3 最终的效果
- 3.4 最终的代码和使用
- 3.5 完整的聊天记录
4 结语

1 前言 🔗

今天继续这个新的系列，跟大家分享在大模型时代，我们可以如何“玩” Emacs，我们应该怎么用大模型来满足自己对 Emacs 使用的需求。

2 大模型 🔗

这个系列的几个案例，均基于 OpenAI 的 ChatGPT-4o 模型（主要是花了钱，不用浪费不是😀）。大模型能做很多事，这里简单说说我们可以通过 ChatGPT 对 Emacs 做什么：

让 ChatGPT 帮忙阅读代码，解释代码，这样以前看不懂的代码可以通过 ChatGPT 看明白
让 ChatGPT 帮忙写代码，尤其是我们对 Emacs 的配置进行调整，需要写一些函数甚至插件
让 ChatGPT 优化已经写好的代码，让代码更加规范和可读
让 ChatGPT 充当 Emacs 百科，充当 Google 的角色，回答各种配置问题
…

所有的这一切，都需要有一个前提，就是你需要学会「正确的问问题」。我想这个技能，不是因为 ChatGPT 的出现才出现，这个问题亘古至今如此，只是对象，从以前问夫子，到网络时代问网友，再到 AI 时代问大模型，其原理不变其宗。

我们与 ChatGPT 的交流，主要通过提示工程。提示词是有方法论的，网上有很多教程，这里不做介绍。与 AI 交流，其实就跟练剑一样，练的多了，也就会了剑，无他，惟手熟耳！

关于这些案例，我在与 ChatGPT 交谈时，实际上并没有很好地遵循提示工程的“三段式”，比较随性，仅供参考。

3 中文按词移动和删除 🔗

3.1 背景 🔗

大家知道英文的单词之间有空格，而中文的词语之间没有空格，这就导致了中英文之间对于词的处理逻辑完全不同。如果按照英文的逻辑，我们按词来移动光标，就会把所有连在一起的中文句子作为一个“词”，这显然不符合我们中国人的使用习惯。

之前一直用 cireu 大佬的 jieba.el 包，很好用，但是不知道是因为升级了 node 还是因为升级了这个包，突然不能用了，一直报如下的错误，以我这个粗浅的水平捣鼓了半天也没找到解决方法。

map-keymap: Wrong type argument: processp, #[0 “�� \”!&�" [“JIEBA-SERVER” jieba-server-start-args make-process :name :command :coding utf-8-emacs-unix :noquery t :connection-type …] 16]

于是就产生了找 ChatGPT 写一个自用版本的想法。

3.2 正确的描述我们的问题 🔗

3.2.1 第一次描述问题 🔗

令人欣喜的是 ChatGPT 给出的初始解决方案就是用 Python 实现的分词部分，这也正是我想要的。

3.2.2 测试以及需求累进的描述 🔗

我们需要对每一个模块进行测试，并且将测试的结果，精确的描述给 ChatGPT，让 ChatGPT 给出更新的代码，然后我们再次重试。

整个过程会遇到很多问题，例如性能的问题，刚开始的版本很卡：

当然，ChatGPT 并不总是正确的，至少我个人觉得他给的 2 个解决方案，并不是很好，我自己想了下给了他一个可能的解决方案来解决性能问题：

以及，我们将 Python 脚本服务化，通过 REST API 的方式来调用：

中间并不是一帆风顺，还会遇到各种报错和警告：

进一步地，我们要考虑在 Mac 上如何优雅的启动这个服务：

最麻烦的就是当你搞定了 Python 脚本和服务，搞定了其中 Backward 方向移动的时候，在 Forward 方向却一直无法正确的移动，此时，也许需要一点点自己的判断力、逻辑思维能力和创造力，我现在回想来，在整个过程中，我自己发挥了 2 个重要的作用：

提供了一个思路是把光标所在的句子文本送去分词，而不是 ChatGPT 提供的把整个 buffer 送过去分词
在经过大量的测试后发现，光标在移动到句子分界线尤其是句首的时候，总是出现问题，于是我扩展了送过去分词的文本范围，一句不行，我把两句一起送过去，这样既解决了性能的问题，也解决了边界的问题，当然这个方法并不优美，算是一个笨方法。

3.3 最终的效果 🔗

最终我们得到了如下的效果：

我们按下 M-f 和 M-b 可以实现中文的按词向前向后移动，而且兼容英文。我们按下 M-DEL 和 M-d 实现了向后和向前按词删除。
我们利用了一个非常简单的 Python 程序来做 jieba 服务后端，其他部分完全通过 elisp 实现。
我们综合的考虑了性能和效果。

3.4 最终的代码和使用 🔗

3.4.1 Python 服务端 🔗

Python 服务端代码：

你可以将端口替换成你想用的端口，我这里随便挑了一个不太会被其他程序占用的端口。

from flask import Flask, request, jsonify
import jieba

# jieba.setLogLevel(jieba.logging.ERROR)

app = Flask(__name__)

@app.route('/segment', methods=['POST'])
def segment_text():
    data = request.json
    text = data.get('text', '')
    if not text:
        return jsonify([])  # 如果没有提供文本，返回一个空列表
    words = jieba.lcut(text)
    return jsonify(words)

if __name__ == '__main__':
    app.run(host='127.0.0.1', port=27350)

此时你就可以通过 python segment.py 来启动这个后端服务了。

如果你想在 Mac 上以 launchctl 和 gunicorn 来启动服务，ChatGPT 也帮我们生成了如下的 plist 文件：

请注意，请务必将下面的文件所有路径替换成你自己的路径！

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
    <key>Label</key>
    <string>com.remacs.segment</string>
    <key>ProgramArguments</key>
    <array>
        <string>/Users/randolph/.venv/py310/bin/gunicorn</string>
        <string>--chdir</string>
        <string>/Users/randolph/bin/python_script</string>
        <string>-w</string>
        <string>4</string>
        <string>-b</string>
        <string>127.0.0.1:27350</string>
        <string>segment:app</string>
    </array>
    <key>EnvironmentVariables</key>
    <dict>
        <key>PATH</key>
        <string>/Users/randolph/.venv/py310/bin:/usr/local/bin:/usr/bin:/bin:/usr/sbin:/sbin</string>
    </dict>
    <key>RunAtLoad</key>
    <true/>
    <key>KeepAlive</key>
    <true/>
    <key>StandardOutPath</key>
    <string>/Users/randolph/Temp/com.remacs.segment.out</string>
    <key>StandardErrorPath</key>
    <string>/Users/randolph/Temp/com.remacs.segment.err</string>
</dict>
</plist>

然后我们可以通过如下的命令来启动这个服务：

launchctl load ~/Library/LaunchAgents/com.remacs.segment.plist

3.4.2 elisp 代码 🔗

(require 'request)

(defun call-jieba-segment (text)
  "调用 RESTful API 使用 jieba 分词 TEXT。"
  (let ((response (request
                    "http://127.0.0.1:27350/segment"
                    :type "POST"
                    :data (json-encode `(("text" . ,text)))
                    :headers '(("Content-Type" . "application/json"))
                    :parser 'json-read
                    :sync t)))
    ;; (message "请求状态: %s" (request-response-status-code response))
    ;; (message "请求响应: %S" (request-response-data response))
    (if (not (eq (request-response-status-code response) 200))
        (error "调用 jieba 分词 API 失败: %s"
               (request-response-status-code response))
      (request-response-data response))))

(defun get-current-sentence ()
  "获取当前光标所在的句子。"
  (save-excursion
    (let (beg end)
      (setq beg (progn (backward-sentence) (point)))
      (setq end (progn (forward-sentence) (forward-sentence) (point)))
      (buffer-substring-no-properties beg end))))

(defun get-segmented-words ()
  "获取当前句子的分词结果。"
  (let* ((sentence (get-current-sentence))
         (words (call-jieba-segment sentence)))
    (append words nil)))

(defun get-sentence-boundaries ()
  "获取当前句子的起始和结束位置。"
  (save-excursion
    (let (beg end)
      (setq beg (progn (backward-sentence) (point)))
      (setq end (progn (forward-sentence) (forward-sentence) (point)))
      (cons beg end))))

(defun backward-word-by-jieba ()
  "基于 jieba 分词结果向后移动一个单词。"
  (interactive)
  (let* ((words (get-segmented-words))
         (pos (point))
         (boundaries (get-sentence-boundaries))
         (sentence-start (car boundaries))
         (word-starts (let ((start sentence-start)
                            starts)
                        (dolist (word words)
                          (setq starts (append starts (list start)))
                          (setq start (+ start (length word))))
                        starts)))
    (catch 'break
      (dolist (start (reverse word-starts))
        (when (< start pos)
          (goto-char start)
          (throw 'break nil))))))

(defun backward-delete-word-by-jieba ()
  "基于 jieba 分词结果向后删除一个单词。"
  (interactive)
  (let* ((words (get-segmented-words))
         (pos (point))
         (boundaries (get-sentence-boundaries))
         (sentence-start (car boundaries))
         (word-starts (let ((start sentence-start)
                            starts)
                        (dolist (word words)
                          (setq starts (append starts (list start)))
                          (setq start (+ start (length word))))
                        starts)))
    (catch 'break
      (dolist (start (reverse word-starts))
        (when (< start pos)
          (delete-region start pos)
          (throw 'break nil))))))

(defun forward-word-by-jieba ()
  "基于 jieba 分词结果向前移动一个单词。"
  (interactive)
  (let* ((words (get-segmented-words))
         (pos (point))
         (boundaries (get-sentence-boundaries))
         (sentence-start (car boundaries))
         (word-starts (let ((start sentence-start)
                            starts)
                        (dolist (word words)
                          (setq starts (append starts (list start)))
                          (setq start (+ start (length word))))
                        starts)))
    (catch 'break
      (dolist (start word-starts)
        (when (> start pos)
          (goto-char start)
          (throw 'break nil))))))

(defun forward-delete-word-by-jieba ()
  "基于 jieba 分词结果向前删除一个单词。"
  (interactive)
  (let* ((words (get-segmented-words))
         (pos (point))
         (boundaries (get-sentence-boundaries))
         (sentence-start (car boundaries))
         (sentence-end (cdr boundaries))
         (word-starts (let ((start sentence-start)
                            starts)
                        (dolist (word words)
                          (setq starts (append starts (list start)))
                          (setq start (+ start (length word))))
                        starts)))
    (catch 'break
      (dolist (start word-starts)
        (when (> start pos)
          (delete-region pos start)
          (throw 'break nil)))
      ;; 如果没有找到大于 pos 的分词起始位置，则删除到句子的结束位置
      (when (< pos sentence-end)
        (delete-region pos sentence-end)))))

;; 将函数绑定到快捷键
(global-set-key (kbd "M-b") 'backward-word-by-jieba)
(global-set-key (kbd "M-DEL") 'backward-delete-word-by-jieba)
(global-set-key (kbd "M-f") 'forward-word-by-jieba)
(global-set-key (kbd "M-d") 'forward-delete-word-by-jieba)

3.5 完整的聊天记录 🔗

这个案例，是我最近这段时间花时间最多，最复杂的案例，当然主要原因也是我自己水平有限。因此这个聊天记录里，有很多非常低级的问题，最终生成的代码也应该有很大的提升空间，仅供参考。

与 ChatGPT 的完整聊天记录

4 结语 🔗

今天这个案例，是一个相对复杂的案例，它涉及到了 Emacs 和外部服务之间的交互，整个聊天过程也比较复杂，除了 ChatGPT 之外，还需要动很多脑筋想办法解决问题。最终实现自己需求的那一刻，那份满足感难以言表。

后续，将会继续分享几个案例。

Org mode 代码块的出错信息
org-super-links 链接与反链改造
…

我也会持续的使用 ChatGPT 和 Emacs，持续分享我的心得，感谢您的阅读。

大模型时代我们怎么玩Emacs：1. 中英文输入时的空格

Mon, 20 May 2024 21:22:18 +0800

1 概述
2 大模型
3 中英文输入时的空格
- 3.1 背景
- 3.2 正确的描述我们的问题
- 3.3 最终的效果
- 3.4 最终生成的代码
- 3.5 完整的聊天记录
4 结语

1 概述 🔗

今天开始一个新的系列，跟大家分享在大模型时代，我们可以如何“玩” Emacs，我们应该怎么用大模型来满足自己对 Emacs 使用的需求。

2 大模型 🔗

让 ChatGPT 帮忙阅读代码，解释代码，这样以前看不懂的代码可以通过 ChatGPT 看明白
让 ChatGPT 帮忙写代码，尤其是我们对 Emacs 的配置进行调整，需要写一些函数甚至插件
让 ChatGPT 优化已经写好的代码，让代码更加规范和可读
让 ChatGPT 充当 Emacs 百科，充当 Google 的角色，回答各种配置问题
…

关于这些案例，我在与 ChatGPT 交谈时，实际上并没有很好地遵循提示工程的“三段式”，比较随性，仅供参考。

3 中英文输入时的空格 🔗

3.1 背景 🔗

中文和英文的输入，到底要不要加空格，是一个很有意思的话题。很多人喜欢在中文和英文之间加上空格，有些人不喜欢。如果要加空格，又会遇到一致性的问题，就是如何保证一篇文章的整体风格的统一，要么都加，要么都不加。除了一致性问题，还会遇到在某些特殊的场合不应该加，比如在一个链接里，就不应该在中英文之间加空格。

我自己倾向于加上空格，这样在阅读和导出为 HTML 或其他格式时，更加美观。

前几年，试用过 pangu-spacing 这个包，用了一段时间之后发现几个问题：

默认情况下，它只是通过 Overlay 让你看上去在中英文之间加了空格，实际上没有加，这会导致在导出为其他文件如 HTML 时没有加空格。
如果通过 (setq pangu-spacing-real-insert-separtor t) 设置在中英文之间真实加上空格，那会出现一个致命的问题，它会默认把整个文档的所有中英文之间加上空格，甚至类似 [[file:中文English文件夹名/中文English.png]] 这种链接，也会自动在中英文之间加上空格，这样就破坏了链接的结构。

请注意，它的修改范围是整个文档，这在一个很大的已经有很多内容的 Org 文档里，简直就是一个灾难。
具有强制性，无法删除我们不想要的空格

3.2 正确的描述我们的问题 🔗

下面我们通过 ChatGPT 看看能否解决这个痛点问题，首先，我们需要将问题正确的描述出来，让大模型理解我们的需求是什么。

3.2.1 第一次描述问题 🔗

3.2.2 测试之后的问题描述 🔗

3.2.3 额外的需求描述 🔗

…

3.3 最终的效果 🔗

通过不断的测试 ChatGPT 生成的代码，我们得到了一个非常好的实现（对我个人来说满足我的需求），我们可以通过 (auto-space-mode t) 的方式开启中英文之间自动加空格，也可以通过 (auto-space-mode nil) 来关闭这个模式。

它与 pangu-spacing 相比有哪些特点呢：

足够安全：只作用于输入的时候，不会改变文件原有的中英文布局
真实空格：添加的是空格，并且可以删除，非强制
兼容性考虑：如果已经手动输入了空格就不会再插入空格
不考虑标点符号：先只考虑中英文和数字，因为标点在 org 里比较复杂，有很多表示强调的符号不应该自动加空格

3.4 最终生成的代码 🔗

(defun add-space-between-chinese-and-english ()
  "在中英文之间自动添加空格。"
  (let ((current-char (char-before))
        (prev-char (char-before (1- (point)))))
    (when (and current-char prev-char
               (or (and (is-chinese-character prev-char) (is-halfwidth-character current-char))
                   (and (is-halfwidth-character prev-char) (is-chinese-character current-char)))
               (not (eq prev-char ?\s))) ; 检查前一个字符不是空格
      (save-excursion
        (goto-char (1- (point)))
        (insert " ")))))

(defun is-chinese-character (char)
  "判断字符是否为中文字符。"
  (and char (or (and (>= char #x4e00) (<= char #x9fff))
                (and (>= char #x3400) (<= char #x4dbf))
                (and (>= char #x20000) (<= char #x2a6df))
                (and (>= char #x2a700) (<= char #x2b73f))
                (and (>= char #x2b740) (<= char #x2b81f))
                (and (>= char #x2b820) (<= char #x2ceaf)))))

(defun is-halfwidth-character (char)
  "判断字符是否为半角字符，包括英文字母、数字和标点符号。"
  (and char (or (and (>= char ?a) (<= char ?z))
                (and (>= char ?A) (<= char ?Z))
                (and (>= char ?0) (<= char ?9))
                )))

(defun delayed-add-space-between-chinese-and-english ()
  "延迟执行，在中英文之间自动添加空格。"
  (run-with-idle-timer 0 nil 'add-space-between-chinese-and-english))

(define-minor-mode auto-space-mode
  "在中英文之间自动添加空格的模式。"
  :lighter " Auto-Space"
  :global t
  (if auto-space-mode
      (add-hook 'post-self-insert-hook 'add-space-between-chinese-and-english)
    (remove-hook 'post-self-insert-hook 'add-space-between-chinese-and-english)))

3.5 完整的聊天记录 🔗

与 ChatGPT 的完整聊天记录

4 结语 🔗

这个系列的分享，只是提供了一个新的思路，我们在这个伟大的时代，要善于利用大模型达到我们的目标。当然，我的这些分享，在大牛面前，什么都不是，大佬分分钟都能做到而且做的更好。但从一个产品经理的角度，从一个代码经验近乎小白的角度，似乎有那么一些意义。

后续，将会继续分享几个案例。

中文按词移动和删除
Org mode 代码块的出错信息
org-super-links 链接与反链改造
…

我也会持续的使用 ChatGPT 和 Emacs，持续分享我的心得，感谢您的阅读。

面向产品经理的Emacs教程：34. Emacs里的表格

Thu, 22 Feb 2024 14:05:31 +0800

1 课程回顾
2 概述
3 Emacs里的表格
- 3.1 table.el
- 3.2 org-table.el
4 结语

1 课程回顾 🔗

通过上节课，我们学习了如何升级 Emacs 的插件，以及遇到报错应该如何处理。

今天我们来学习 Emacs 里的表格。

2 概述 🔗

Emacs 里是否可以处理表格？当然可以。尤其是 Org-mode，被称为文本界的 Office 套件，必须可以处理表格。今天我们来学习 Emacs 里的表格。

今天的主要内容有：

创建表格
导出表格
表格公式

3 Emacs里的表格 🔗

3.1 table.el 🔗

Emacs 自带 table.el 包，可以处理纯文本表格，比如我们可以通过 table-insert 命令在当前光标处插入一个表格：

我们可以通过 <TAB> 键在不同的单元格里移动和编辑。

如果要使用这个包，需要注意以下几点：

你需要使用等宽字体，或调整好你的中英文字体大小比例，这样不至于表格会错乱不对齐
插入的表格，不依赖于文件格式，在任何缓冲区都可以插入，可以理解为类似于像 ASCII 艺术的那种感觉
table.el 更关注的是文本表格的视觉布局和组织，不支持公式等复杂功能

3.2 org-table.el 🔗

下面讲一讲更加实用的 org-table.el 包，这个包是 Org-mode 官方支持的表格功能，它几乎能做到 Office 里做到的事，区别在于它是基于纯文本的，而 Office 不是。

你问我？我当然更加喜欢基于纯文本的 Org-mode，如果不是要和其他人协作，我甚至可能会卸载 Office。

下面就简单讲一讲 Org-mode 里的表格操作。

3.2.1 表格基本操作 🔗

3.2.1.1 创建表格 🔗

我自己创建表格用的是 yasnippet 的模板，只需要输入 <ta 再按下 <tab> 键，Emacs 就会自动在 Org 文档里创建一个表格：

这个 yasnippet 的模板如下：

# -*- mode: snippet -*-
# name: table
# key: <ta
# --
#+CAPTION: $1
#+NAME: ${1:tablename}
#+ATTR_LATEX: :float nil :environment tabularx :width \textwidth :align
| ${2:key} | ${3:description} |
|-$0

3.2.1.2 表格的编辑 🔗

我自己常用的表格编辑动作如下，供参考：

表 1: Emacs Org mode 表格常用编辑动作

快捷键	函数	作用
<tab>	org-cycle	进入下一个单元格，同时可以自动调整表格格式
<backtab>	org-shifttab	进入上一个单元格，同时可以自动调整表格格式
C-c C-c	org-ctrl-c-ctrl-c	自动调整表格格式
RET	org-return	进入下一行
C-c RET	org-ctrl-c-ret	在当前行下加一行分隔线和新行然后移动到新行
C-c -	org-ctrl-c-minus	在当前行下加一行分隔线
M-up	org-metaup	交换当前行和上一行
M-down	org-metadown	交换当前行和下一行
M-left	org-metaleft	交行当前列和左边一列
M-right	org-metaright	交换当前列和右边一列
M-S-up	org-shiftmetaup	删除当前行
M-S-down	org-shiftmetadown	在当前位置新增空行并将当前行下移一行
M-S-left	org-shiftmetaleft	删除当前列
M-S-right	org-shiftmetaright	在当前位置新增空列并将当前列右移一列
	org-table-blank-field	清空当前单元格
M-a	org-backward-sentence	跳转到当前单元格首
M-e	org-forward-sentence	跳转到当前单元格尾
C-<tab>	org-ctrl-c-tab	折叠或展开当前列
C-c '	org-edit-special	在一个新buffer输入表格公式
C-c =	org-table-eval-formula	在当前单元格输入公式
C-c *	org-ctrl-c-star	重新按照公式计算和更新表格
C-c }	org-table-toggle-coordinate-overlays	是否显示表格的参考线更便于编写公式

3.2.2 表格公式 🔗

下面着重说下Org mode里表格的公式。

3.2.2.1 如何引用行、列、分隔线和单元格 🔗

行

用 @# 来表示第几行：如 @1 表示第一行， @0 表示当前行
用 @> 来表示最后一行
用 @< 来表示第一行
用 @+3 来表示当前行后3行： @-2 表示当前行前2行

列

用 $数字 来表示第几列：如 $1 表示第一列， $0 表示当前列
用 $> 来表示最后一列
用 $< 来表示第一列
用 $+3 来表示当前列后3列： $-2 表示当前列前2列

单元格

用 @#$# 来表示第几行第几列的单元格，如 @2$3 表示第二行第三列
用 @0$0 表示当前单元格

分隔线

用 @I 表示第一个水平分隔线，用 @II 表示第二个， @III 表示第三个
用 @-I 表示在当前行上一个水平分隔线， @+I 表示当前行下一个水平分隔线
用 @III+2 表示在第三个水平分隔线后2行

范围

用 .. 表示范围，如 @2..@> 表示第2行到最后一行

结果的格式

用 ;xx 来表示结果的格式规定，如 ;%.1f 表示保留到小数点后1位

3.2.2.2 常用例子 🔗

Org-mode 的表格支持两种公式，我们先讲 calc 格式或 elisp 的代码公式，我们可以根据需要灵活运用。

3.2.2.2.1 求平均 🔗

假设我们的原始表格如下：

表 2: 测试表格1

年份	销售额
2020	135
2021	150
2022	175
2023	160
平均

那么我们如何来写这个公式呢，我们可以将光标放到总计对应的那个空单元格，然后按下 C-c ' 后编辑公式： @>$2=vmean(@I$2..@II$2) ，编辑完后，表格就变成了如下：

| 年份 | 销售额 |
|------+--------|
| 2020 |    135 |
| 2021 |    150 |
| 2022 |    175 |
| 2023 |    160 |
|------+--------|
| 平均 |        |
#+TBLFM: @>$2=vmean(@2$2..@5$2);%.1f

我们可以使用 ;%.1f 来表示公式计算后的格式，如这个代表精确到小数点后一位。

然后我们在最后一个单元格里按下 C-c * (或将光标移动到公式行按 C-c C-c ) 就可以得到最终结果了：

年份	销售额
2020	135
2021	150
2022	175
2023	160
平均	155.0

3.2.2.2.2 求和 🔗

还是针对上面的表格，求和的公式为 @>$2=vsum(@I$2..@II$2)

最终的结果为：

年份	销售额
2020	135
2021	150
2022	175
2023	160
平均	620

3.2.2.2.3 单元格拼接 🔗

针对上面那个表格，如果我们想要增加一列，新的列由左边两列拼接而来，如 2020年的销售额为135万 ，此时编辑公式为 (concat $1 "年的销售额为" $2 "万")

最终的结果为：

年份	销售额	新的文本
2020	135	2020年的销售额为135万
2021	150	2021年的销售额为150万
2022	175	2022年的销售额为175万
2023	160	2023年的销售额为160万

3.2.2.2.4 多个公式 🔗

如果有多个公式，在 #+TBLFM: 的公式一行，通过 :: 将多个公式连接起来，如下：

| 年份 | 销售额 | 拼接的文本  |
|------+--------+-------------|
| 2020 |    160 | 2020年160万 |
| 2021 |    150 | 2021年150万 |
| 2022 |    175 | 2022年175万 |
| 2023 |    160 | 2023年160万 |
|------+--------+-------------|
| 平均 | 161.25 |             |
| 总计 |    645 |             |
#+TBLFM: @>>$2=vmean(@I$2..@II$2)::@>$2=vsum(@I$2..@II$2)::@2$3..@5$3='(concat $1 "年" $2 "万")

基本上学会上面这些常用的公式，能解决日常工作的大部分问题了，如果还有别的诉求，可以详细阅读 Org-mode 的官方文档。

3.2.3 列表表格 🔗

我们在日常工作中，还会遇到一个诉求，就是更加复杂的表格，例如：

在一个单元格里放一张图片
在一个单元格里放一些项目符号
在一个单元格里放多个段落文本
…

上述诉求，用常规的 org-table.el 是无法实现的，此时，我们需要 org-mode-ox-odt 这个包的帮助。

3.2.3.1 安装配置 🔗

(add-to-list 'package-archives
             '("ox-odt" . "https://kjambunathan.github.io/elpa/"))

(use-package ox-odt
  :ensure t
  :after (org ox ox-html)
  :init
  (add-to-list
   'org-export-filter-parse-tree-functions
   (defun org-html--translate-list-tables (tree backend info)
     (if (member backend '(html latex))
         (org-odt--translate-list-tables tree backend info)
       tree)))
  )

3.2.3.2 如何使用 🔗

安装完这个包后，我们就可以通过 list table （列表表格）来构建复杂的表格了。下面是一个示例：

#+CAPTION: 示例列表表格
#+NAME: 示例列表表格
#+ATTR_ODT: :list-table t
-
  - 标题1
  - 标题2
  - 标题3
- ----------------
  - 2007
  -
    - 很好
    - 非常好
    - 特别好
  -
    - [ ] 待办1
    - [ ] 待办2
    - [ ] 待办3
- ---------------
  -
     噼里啪啦第一段话

     噼里啪啦第二段话
  -
     [[https://orgmode.org/resources/img/org-mode-unicorn.svg]]
  -
     | 标题1 | 标题2     |
     |-------+-----------|
     |  2008 | good      |
     |  2010 | wonderful |

然后在我们按下 C-c C-e 选择 html 的格式进行导出的时候，可以看到这个复杂表格已经按照我们的预期生成了：

4 结语 🔗

通过今天的学习，我们了解了在 Emacs/Org-mdoe 内的表格，我们了解到如何在 Org-mode 里处理复杂一点的表格，如何使用公式，如何通过列表表格来生成更加复杂的表格，Org-mode 简直就是纯文本界的 Office！

这节课的配置文件的快照见：emacs-config-l34.org

你也可以在这里查看最新的配置文件。

面向产品经理的Emacs教程：33. Emacs升级插件

Sun, 04 Feb 2024 10:03:33 +0800

1 课程回顾 🔗

通过上节课，我们了解了如何通过 Emacs 来管理简历，以后的个人简历只需要修改 Org 文件就可以了，只需要关心内容，不需要关心格式，文本即一切！

今天我们来学习如何升级 Emacs 的插件，以及如何解决升级过程中出现的问题。

2 概述 🔗

Emacs 的各种插件（package）丰富多样，功能越来越强大和完善，对于插件的升级，相信很多人都有一个烦恼：升级了插件，怕之前的配置不兼容了，不升级插件吧，可能新版插件提升了性能，增加了很多新的功能，一个字——纠结！

因此升级插件和将插件保持在一个稳定的版本，是一个平衡，看自己的需要，以及自己的性格。就我个人而言，我比较倾向于使用较新版的插件，体验新的功能。

那升级插件，有好几种方式：

通过 auto-package-update.el 插件来实现全部插件的定时自动升级
通过 package-menu-filter-upgradable 命令手动对某些包升级
隔一段时间，删除 elpa 目录，再重新启动 Emacs，Emacs 会自动安装最新版的插件

就我个人而言，我倾向于删除 elpa 目录的方式，简单粗暴。

3 auto-package-update.el 插件 🔗

我们可以通过 auto-package-update.el 插件实现对所有插件的定时全量自动更新。

我们只需要将如下配置添加到我们的配置文件即可：

(use-package auto-package-update
  :ensure t
  :hook (after-init . auto-package-update-maybe)
  :if (not (daemonp))
  :custom
  (auto-package-update-interval 30)              ; 每30天检查一次
  (auto-package-update-prompt-before-update t)   ; 升级前提示
  (auto-package-update-delete-old-versions t)    ; 删除旧版本
  (auto-package-update-hide-results t))

我们通过 list-packages 界面下，执行 package-menu-filter-upgradable (/ u) 命令查看当前哪些包可以升级：

这张图展示了所有可以升级的包列表：

这张图展示了已经安装了包列表：

此时将光标移动到想要升级的包那一行，按下 i 键标记要升级的包，按下 x 执行即可：

5 删除 elpa 文件夹重新安装 🔗

下面我们来学习另外一种更加粗暴的方式，把 .emacs.d 文件夹下的 elpa 文件夹（装所有插件的文件夹）全部删除，此时重新启动 Emacs 时，Emacs 会自动下载最新版的插件包。

自从我开始做这个系列，已经过了接近一年了，很多插件都没更新，现在一口气更新所有的插件，我们尝试解决插件更新后的配置调整问题。

在实际测试后，发现升级了包后并没有发现冲突，于是我改了下 cape 这个包的配置，用来进行演示。

5.1 删除 elpa 文件夹再重新启动 🔗

为了安全，建议不要直接删除，可以使用 mv elpa elpa.bak 命令将文件夹重命名，这样万一出现意外，我们随时可以恢复。

我们删除/重命名完 elpa 文件夹后，再次启动 Emacs，可以看到，Emacs 报了以下的错误：

我们可以看到 cape-super-capf 这个函数名的定义出了问题，进一步地，我们可以通过在启动 Emacs 的时候添加 --debug-init 的参数，来获得具体出错的 backtrace 信息。

知道了这个错误，我们可以查看 cape 这个包的相关网站（主要是 Github 首页以及相关的 issue），通过搜索，我们看到，这位大神把 cape-super-capf 这个函数名，改成了 cape-capf-super ，因此我们要做的就是修改这个变量名，然后重启 Emacs，至此，我们成功修复了该问题：

6 结语 🔗

通过今天的学习，我们了解了如何升级各种插件包，我们可以通过 --debug-init 的方法来尝试找到各种启动问题，然后逐个解决。

这节课的配置文件的快照见：emacs-config-l33.org

你也可以在这里查看最新的配置文件。

面向产品经理的Emacs教程：32. 通过Emacs来管理简历

Wed, 31 Jan 2024 13:35:22 +0800

1 课程回顾 🔗

通过上节课，我们了解了如何通过 Emacs 看视频，写视频笔记，这在后疫情时代，对听网课，梳理自己的知识体系非常有帮助。

今天我们来学习如何通过 Emacs 来管理简历。

2 概述 🔗

以前我的简历是这样的，通过一个 Word 文档来管理自己的简历：

但是 Word 文档的麻烦，需要花很多时间去调整格式，对于我一个习惯了 Org-mode，坚信内容为上的人来说，简直无法忍受，我们为什么不通过 Emacs 和 Org-mode 来管理自己的简历呢？

这节课，我们将学习如何通过 Emacs 的 Org-mode 来管理自己的简历。

3 大体思路 🔗

中间陆陆续续试过一些包，总体试用感觉比较麻烦，不太简约，最终还是选定了 Org-mode 转成 Latex PDF 的方式来实现简历的管理。

这个方式整体思路是，我们通过创建一个 Org 格式的简历模板，针对不同的人，或者不同的阶段，只需要对其中的内容进行替换就可以了。

4 Resume模板 🔗

#+TITLE: Randolph的简历
#+OPTIONS: toc:nil H:10 tex:t author:nil date:nil
#+STARTUP: hidestars indent
#+LaTex_CLASS: article
#+LaTeX_CLASS_OPTIONS: [letterpaper]
#+LaTeX_HEADER: \usepackage{/Users/randolph/org/template/resume/resume}
#+LATEX_HEADER: \usepackage[explicit]{titlesec}
#+LATEX_HEADER: \usepackage[left=0.4in,right=0.5in,top=0.5in,bottom=0.5in]{geometry}
#+LATEX_HEADER: \pagenumbering{gobble} % remove page number
#+LaTeX_HEADER: \usepackage{tabularx}
#+LaTeX_HEADER: \hypersetup{colorlinks=true, urlcolor={url-blue}}
#+LaTeX_HEADER: \usepackage{enumitem}
#+LaTeX_HEADER: \setlist{leftmargin=0.25in,nosep}
#+LATEX_HEADER: \usepackage{xeCJK,fontspec,xunicode,xltxtra}
#+LATEX_HEADER: \setCJKmainfont{Microsoft YaHei}
#+LATEX_HEADER: \setCJKmonofont{Microsoft YaHei}
#+LATEX_HEADER: \setCJKfamilyfont{Microsoft YaHei}{Microsoft YaHei}
#+LATEX_HEADER: \setmainfont{Microsoft YaHei}
#+LATEX_HEADER: \setmonofont{Source Code Pro}
#+LATEX_HEADER: \usepackage{setspace}
#+LATEX_HEADER: \onehalfspacing


#+BEGIN_CENTER
| 手机：(+86) 1860xxxxxxxx | 邮箱：[[mailto:xxxxxxx@gmail.com][xxxxxx@gmail.com]] |
#+END_CENTER

* 自我评价
- 走在人工智能人机交互领域应用@@latex:{\color{red}@@ *创新* @@latex:}@@最前端
- 一个有技术背景、有商业洞察力、能力@@latex:{\color{red}@@ *综合* @@latex:}@@的产品经理
- 富有 @@latex:{\color{red}@@ *好奇心和激情* @@latex:}@@

* 工作经历
** xx集团 ｜ AI研究院 ｜ 资深产品经理
*** 2020.11 至今

- 带领团队从 0 开始负责xxxx的工作。
  + xxxx；
  + xxxx；
\smallskip
- 赋能集团xxxx。
  + xxxx *加粗* xxxx；
  + xxxx；

** xxx ｜ AI产品经理
*** 2020.9 - 2020.11
- 负责xxx。


* 教育经历
** xxx大学
*** 2006 - 2008
生物信息技术，硕士，xxxxxx

** xxx 大学
*** 2002 - 2006
生物信息技术，本科

* 语言及技能
- CET-6，熟练的英语读写听说能力
- 有研发、服务、产品等技术背景
- 有带领团队经验
- 有销售经验和市场洞察力
- 有人工智能、大模型、知识图谱、NLP、互联网等领域经验
- 有良好的沟通表达能力
- 富有好奇心和激情

根据这个模板内容，通过 C-c C-e l o (org-latex-export-to-pdf) 转换成 PDF 文件，大致格式如下：

整个模板分为以下几个部分：

自我评价
工作经历
教育经历
语言及技能

注：

我们可以使用 Org-mode 自带的粗体格式来加粗
我们可以使用 @@latex:{\color{red}@@ 需要变成红色的文字 @@latex:}@@ 包裹让字的颜色变化
我们可以通过 \smallskip 让某些段落之间增加距离

自此，我们就可以套用这个模板来管理我们的简历，我们只需要关注内容，而不需要去管格式和排版了，愉快！

5 结语 🔗

通过今天的学习，我们了解了如何在 Emacs 里通过 Org-mode 和 Latex 来管理简历，这节课没有配置上的变化，我把这个模板放到 Github 上，大家各取所需。

这节课的模板文件的见：resume-template.org

你也可以在这里查看最新的配置文件。

面向产品经理的Emacs教程：31. 通过Emacs来看视频

Fri, 19 Jan 2024 15:35:22 +0800

1 课程回顾 🔗

通过上节课，我们了解了如何在 Emacs 里使用浏览器，我们可以通过 EWW 来浏览一些文字型的网页，并且达到一个非常好的去广告效果，我们可以通过强大的 EAF 在 Emacs 里使用真正的 Chromium 浏览器，非常强大。

今天我们来学习如何通过 Emacs 来看视频。

2 概述 🔗

肯定有同学会纳闷，看视频就是看视频，为什么要通过 Emacs 来看视频，有什么好处？为什么看个视频还要搞的这么麻烦？

你是否曾经遇到这样的场景呢？

你正在看一个教学视频
边看视频边做笔记（电子笔记）
时不时需要截屏
还要能让自己做的笔记和视频的时间戳对应上
…

而要实现上面的场景，我们完全可以通过 Emacs 来做到，通过 Emacs 的 Org mode 来记笔记，通过我们今天要介绍的 mpvi 来实现上述功能。

3 mpvi 🔗

mpvi 插件可以让 Emacs 来控制 mpv 视频播放，并与 Org-mode 结合起来。

mpvi 插件是 emacs-china 论坛的一位道友开发的，之前名字叫 org-mpvi ，经过改版后，非常好用了。

3.1 mpvi 安装 🔗

3.1.1 依赖 🔗

我们先安装相关的依赖，其中 mpv 是播放器， yt-dlp 是看网络视频的， ffmpeg 用来做视频剪辑操作的， tesseract 用来识别文字：

brew install mpv yt-dlp ffmpeg tesseract

我不需要弹幕，也不看直播，所以没有安装 danmaku2ass 和 seam ，需要的朋友自行安装。

3.1.2 安装 mpvi 插件 🔗

(use-package mpvi
  :ensure t
  :commands (mpvi-open mpvi-seek mpvi-insert)
  :bind (("C-c v o" . mpvi-open)
         ("C-c v s" . mpvi-seek)
         :map mpvi-seek-map
              ("C-i" . my/mpvi-seeking-capture-as-screenshot))
  :config
  ;; 如果不设置这个值，会提示ipc的错误需要你update mpv
  (setq emms-player-mpv-ipc-method 'ipc-server)

  ;; 通过这个函数来对视频截图，我不喜欢使用attach的方式
  (defun my/mpvi-seeking-capture-as-screenshot ()
    "Capture current video screenshot and insert as a link."
    (interactive)
    (with-current-buffer (window-buffer (minibuffer-selected-window))
      (unless (derived-mode-p 'org-mode)
        (user-error "This is not org-mode, should not insert org link")))
    (with-current-buffer (window-buffer (minibuffer-selected-window))
      (when (mpvi-parse-link-at-point)
        (end-of-line) (insert "\n"))
      (let ((foldername (concat (file-name-base (buffer-file-name)) ".assets/"))
            (imgName (concat "img_" (format-time-string "%Y%m%d_%H%M%S") ".png")))
        (if (not (file-exists-p foldername))
            (mkdir foldername))
        (let ((imgPath (concat foldername imgName))
              (relativeFilename (concat (file-name-base (buffer-name)) ".assets/" imgName)))
          (mpvi-screenshot-current-playing imgPath "video")
          (insert (concat "#+DOWNLOADED: screenshot @ "
                          (format-time-string "%Y-%m-%d %a %H:%M:%S" (current-time))
                          "\n#+CAPTION: \n#+ATTR_ORG: :width 600"
                          "\n#+ATTR_LATEX: :width 1.0\\linewidth :float nil\n"
                          "#+ATTR_HTML: :width 600"
                          " :class zoomImage\n[[file:" relativeFilename "]]"))
          ))
      (org-redisplay-inline-images))
    (throw 'mpvi-seek "Capture and insert done."))
  )

其依赖的 emms 包会自动下载安装。

我修改了默认的在 mpvi-seek 界面下的快捷键 C-i ，绑定到了我自己喜欢的截图方式。

3.2 如何使用 🔗

3.2.1 打开视频 🔗

通过 C-c v o 打开一个视频文件，此时会自动调用 mpv 软件来播放这个视频。

3.2.2 视频播放控制 🔗

视频播放控制，最重要的命令是 mpvi-seek ，我绑定到了 C-c v s 快捷键上，按下后，在迷你缓冲区里会展示当前视频的相关信息，如：

当前时间戳
总时长
播放进度
当前播放状态
播放速度

我们可以在迷你缓冲区通过 SPC （空格键）开控制视频的播放与暂停，通过 j, k 控制播放速度，通过 n, p 控制播放进度，通过 C-i 来将当前视频画面截图并插入到Org文档里（这个快捷键绑定的是我重新的函数，具体看上面的配置），其他的操控命令和快捷键如下：

快捷键	说明	条件
, ,	播放链接	光标在视频链接上的时候
, s	进入到 mpvi-seek 界面	光标在视频链接上的时候
, a	更改视频开始时间	光标在视频链接上的时候
, b	更改视频结束时间	光标在视频链接上的时候
, v	预览视频时间戳位置的画面	光标在视频链接上的时候
, c	视频下载转码截取等	光标在视频链接上的时候
i	在buffer中插入时间戳链接	光标在 mpvi-seek 迷你缓冲区界面
SPACE	暂停与播放	光标在 mpvi-seek 迷你缓冲区界面
C-i	插入当前视频截图	光标在 mpvi-seek 迷你缓冲区界面
j/k/l	调整播放速度	光标在 mpvi-seek 迷你缓冲区界面
n/p/N/P/M-n/M-p/C-l	调整播放进度	光标在 mpvi-seek 迷你缓冲区界面
r/C-r	对当前播放页面进行OCR识别并复制结果	光标在 mpvi-seek 迷你缓冲区界面
t/C-t	复制当前页面的字幕	光标在 mpvi-seek 迷你缓冲区界面
v/C-v	切换网络视频 playlist 里的视频	光标在 mpvi-seek 迷你缓冲区界面
o/C-o	切换到默认程序打开当前视频	光标在 mpvi-seek 迷你缓冲区界面
q/C-q	退出 minibuffer	光标在 mpvi-seek 迷你缓冲区界面

3.2.3 在Org文档里记视频笔记 🔗

mpvi 除了能很方便的通过快捷键来进行播放控制外，还有一个非常棒的作用，就是一边看视频，一边做笔记。我们可以在 mpvi-seek 时按下 i 键插入当前视频的链接：

这个链接的展开形式如下：

我们可以把这个链接当作一个 Org-link 来对待，比如使用 C-c C-o 打开这个视频，并跳转到该时间戳。

当我们发现在视频的某一个画面非常好，需要截图插入到 Org 文档中，我们可以使用 C-i 来插入当前视频画面，非常方便：

4 结语 🔗

通过今天的学习，我们了解了如何在 Emacs 里通过 mpvi 插件来看视频，并且与 Org-mode 结合，非常方便的来记视频笔记。

这节课的配置文件的快照见：emacs-config-l31.org

你也可以在这里查看最新的配置文件。

面向产品经理的Emacs教程：30. 在Emacs里使用浏览器

Fri, 05 May 2023 09:12:47 +0800

1 课程回顾
2 概述
3 EWW
- 3.1 关于图片显示
- 3.2 关于快捷键
- 3.3 书签
4 EAF
- 4.1 安装 EAF
- 4.2 配置 EAF
- 4.3 使用 EAF
5 xwidget
6 结语

1 课程回顾 🔗

上节课，我们学习了如何在 Emacs 里通过 calibredb.el 插件看书，通过 Emacs 强大的书签和文本搜索能力、强大的编辑能力，使我们看书做笔记的效率大大提升。

今天我们学习如何在 Emacs 里使用浏览器。

2 概述 🔗

我一直秉承一个观点，Emacs 是一个非常棒的软件，如果能在 Emacs 里实现、并且实现的还不错的任务，如记笔记、写博客、写文档、编程等嗯，尽可能的考虑 All-in-one，但是并非所有的场景都适合用 Emacs 来解决，比如浏览器，尽管 Emacs 里有强大的 EAF，有传统的 EWW，有 xwidget，但独立的浏览器的体验还是更好一些，你可以安装各式各样的扩展，可以安装各种油猴脚本，可以实现各种各样的需求。

那 Emacs 里的浏览器就没有作用了吗？当然不是，至少 EWW 就可以做为一个非常好的看纯文本网站内容的好工具（至少去广告这一点做的太好了）。

当然也一定有不同观点的人，他们希望尽可能的 All-in-one，因此，今天会简单说一说在 Emacs 里使用浏览器。

3 EWW 🔗

EWW (GNU Emacs Web Wowser) 是 Emacs 自带的浏览器，虽然有些年头了，但界面清爽简洁，特别适合终端或者希望专注在文字上的场景（例如看技术文档，看小说😄等），在 Emacs 里打开 EWW 非常简单，直接执行 M-x eww ，然后他会让你输入网址，例如 www.baidu.com ，结果如下：

我们可以找一个文字比较多的网站，例如 EWW 的官方文档，可以看到，整个界面非常简洁：

下面，我们介绍如何对 EWW 进行改造，使它更加符合我们的使用场景和习惯。

3.1 关于图片显示 🔗

就我个人而言，我更倾向于使用 EWW 浏览文字型的网站，因此，我并不希望它显示图片，此时我们可以通过下面的配置来完成：

(use-package shr
  :ensure nil
  :defer t
  :custom
  (shr-inhibit-images t)                ; 不显示图片
  (shr-image-animate nil)               ; 不显示 gif
  )

这样，我们就将所有图片禁止显示，所有图片的位置会以一个 * 来替换：

3.2 关于快捷键 🔗

在 EWW 界面按下 ? 后，可以看到所有的快捷键：

我们可以通过下面的方式来将快捷键定制成自己喜欢的，例如改成我个人习惯使用 Surfingkeys 插件的快捷键：

(use-package eww
  :ensure nil
  :commands eww eww-follow-link
  :hook (eww-mode . visual-line-mode)
  :bind (("\e\e w" . eww)
         :map eww-mode-map
         ("o" . eww-browse-with-external-browser)
         ("D" . eww-forward-url)
         ("S" . eww-back-url)
         ("f" . link-hint-open-link)
         ("TAB" . shr-next-link)
         ("<backtab>" . shr-previous-link)
         ("j" . scroll-up-line)
         ("k" . scroll-down-line)
         )
  :config
  (setq eww-download-directory (expand-file-name "~/Downloads"))
  (setq eww-form-checkbox-symbol "☐")
  (setq eww-form-checkbox-selected-symbol "☑")
  )

这里我们着重说下 link-hint-open-link ，我们按下 f 后，所有链接前面会出现一些候选快捷键，我们按下对应的快捷键就相当于点击了这个链接：

3.3 书签 🔗

书签有两种方式，一种是使用 EWW 的书签，另一种是使用 Emacs 的统一书签，我个人倾向于后者。

3.3.1 EWW 的书签 🔗

EWW 的书签比较简单，直接按下 b (eww-add-bookmark) 添加书签，按下 B (eww-list-bookmarks) 来显示书签列表，在书签列表里，按下 C-k 即可删除书签。

3.3.2 Emacs 自带的书签 🔗

我们按下 C-x r m 来将当前页面添加到书签，然后按下 C-x r l 来展示所有的书签，使用 Emacs 的书签好处在于，它可以对任何 BUFFER 进行书签，比如某个 Org 文件。

需要删除书签，只需要将光标移动到对应的行，然后按下 d 标记删除，再按下 x 确认并执行即可。

4 EAF 🔗

上面介绍的 EWW 主要用在某些特定场景，例如看一些文字型的网站，下面将介绍一个 Emacs 里的大杀器 —— EAF (Emacs Application Framework)。

它可以让我们在 Emacs 里运行高级的桌面程序，如浏览器、PDF阅读器、音乐播放器等，下面是一张使用 EAF 运行浏览器的截图：

这俨然就是一个现代浏览器啊！下面主要介绍一下如何在 MacOS 里安装配置 EAF。

4.1 安装 EAF 🔗

4.1.1 安装依赖 🔗

安装下面的 Python 依赖包（不管是否使用 Python 的 venv 虚拟环境，都可以，这一步建议手动做，并且版本最好都按照下面的指定好，否则安装完后启动 EAF 后容易报错）：

pip3 install -U epc sexpdata tld lxml mac-app-frontmost PyQt6==6.3.1 PyQt6-Qt6==6.3.1 PyQt6-sip PyQt6-WebEngine==6.3.1 PyQt6-WebEngine-Qt6==6.3.1

4.1.2 克隆 EAF 仓库 🔗

我们假定把 EAF 的所有内容都放到 ~/emacs-application-framework 这个文件夹：

git clone --depth=1 -b master https://github.com/emacs-eaf/emacs-application-framework.git ~/emacs-application-framework/

4.1.3 安装 EAF 🔗

cd ~/emacs-application-framework/ && ./install-eaf.py --install-all-apps

注：

./install-eaf.py 有很多有用的参数，其中 --install-all-apps 是安装 EAF 所有的应用，我倾向于这种方式是因为可以随时通过配置文件里 require 相应的模块来启用相关应用，而不用再次安装；

你也可以不加 --install-all-apps 参数，这样在安装的时候，它会提示你每一个应用你是否需要安装，如下图：

4.2 配置 EAF 🔗

我们按照自己的要求启用相应的应用即可：

(use-package eaf
  :load-path "~/emacs-application-framework"
  :config
  (require 'eaf-browser)                ; 启用浏览器
  ;; (require 'eaf-pdf-viewer)          ; 启用PDF阅读器
  )

4.3 使用 EAF 🔗

安装完后，我们执行 M-x eaf-open-browser ，它会提醒输入链接，我们输入URL，然后就可以愉快的使用啦：

值得一提的是，EAF 的浏览器也支持按下 f 键快速选择链接，这一点非常方便：

5 xwidget 🔗

我们在安装 emacs-plus 时，如果加上了 --with-xwidget 选项，那么 Emacs 就可以支持 xwidget 浏览器。我们使用 M-x xwidget-webkit-browse-url 来启动：

6 结语 🔗

通过今天的学习，我们了解了如何在 Emacs 里使用浏览器，在不同的场景需求下，我们可以选择不同的方案。当然，从我个人的角度来讲，我还是倾向于使用单独的浏览器😄

这节课的配置文件的快照见：emacs-config-l30.org

你也可以在这里查看最新的配置文件。